x86-64 命令一覧

概要と記号

add5.cをgcc -S add5.cでコンパイルした結果 add5.s(余計なものの削除後)を用いて， x86-64アセンブリ言語の概要と記号を説明します．

• $ gcc -S add5.cを実行(コンパイル)すると，アセンブリコードadd5.sが生成されます．(結果は環境依存なので，add5.sの中身が違ってても気にしなくてOK)
• ドット記号 . で始まるのはアセンブラ命令(assembler directive)です．
• コロン記号 : で終わるのはラベル定義です．
• シャープ記号 # から行末までと，/*と*/で囲まれた範囲(複数行可)はコメントです．
• movq %rsp, %rbp は機械語命令(2進数)の記号表現(ニモニック(mnemonic))です．movqが命令でオペコード(opcode)，%rspと%rbpは引数でオペランド(operand)と呼ばれます．
• ドル記号 $ で始まるのは即値(immediate value，定数)です．
• パーセント記号 %で始まるのはレジスタです．
• -4(%rbp)は間接メモリ参照です．この場合は「%rbp-4の計算結果」をアドレスとするメモリの内容にアクセスすることを意味します．

命令サフィックス

• 間接メモリ参照ではサイズ指定が必要です (「何バイト読み書きするのか」が決まらないから)
• AT&T形式では命令サフィックス(instruction suffix)でサイズを指定します． 例えばmovq $10, -8(%rbp)のqは， 「メモリ参照-8(%rbp)への書き込みサイズが8バイト」であることを意味します．

• Intel形式ではメモリ参照の前に，BYTE PTRなどと指定します．
• 他のオペランドからサイズが決まる場合は命令サフィックスを省略可能です． 例えば，movq %rax, -8(%rsp)はmov %rax, -8(%rsp)にできます． mov命令の2つのオペランドはサイズが同じで %raxレジスタのサイズが8バイトだからです．

即値(定数)

• 即値(immediate value，定数)には$をつけます
• 上の例の定数は最後以外は全部，値が同じです
• GNUアセンブラでは文字定数の値はASCIIコードです． 上の例では，文字'J'の値は74です．
• バックスラッシュでエスケープできる文字は， \b, \f, \n, \r, \t, \", \\ です． また\123は8進数，\x4Fは16進数で指定した文字コードになります．
• 多くの場合，即値は32ビットまでで， オペランドのサイズが64ビットの場合， 32ビットの即値は，64ビットの演算前に 64ビットに符号拡張 されます (ゼロ拡張だと 負の値が大きな正の値になって困るから)

# asm/add-imm2.s
    .text
    .globl main
    .type main, @function
main:
    movq $0, %rax
    addq $-1, %rax
    ret
    .size main, .-main

0 + 0xFFFFFFFFFFFFFFFF = 0xFFFFFFFFFFFFFFFF

$ gcc -g add-imm2.s
$ gdb ./a.out -x add-imm2.txt
Breakpoint 1, main () at add-imm2.s:8
8	    ret
7	    addq $-1, %rax
$1 = 0xffffffffffffffff
# 0xffffffffffffffff が表示されていれば成功

# asm/add-imm.s
    .text
    .globl main
    .type main, @function
main:
    movq $0, %rax
    addl $0xFFFFFFFF, %eax          # OK (0xFFFFFFFF = -1)
#    addq $0xFFFFFFFF, %rax         # NG (0x7FFFFFFFを超えている)
    addq $0xFFFFFFFFFFFFFFFF, %rax  # OK (0xFFFFFFFFFFFFFFFF = -1)
    addq $0x7FFFFFFF, %rax          # OK
    addq $-0x80000000, %rax         # OK
    addq $0xFFFFFFFF80000000, %rax  # OK (0xFFFFFFFF80000000 = -0x80000000)
    ret
    .size main, .-main

$ gcc -g add-imm.s
$ gdb ./a.out -x add-imm.txt
Breakpoint 1, main () at add-imm.s:7
7	    addl $0xFFFFFFFF, %eax          # OK (0xFFFFFFFF = -0x1)
9	    addq $0xFFFFFFFFFFFFFFFF, %rax  # OK (0xFFFFFFFFFFFFFFFF = -0x1)
1: /x $rax = 0xffffffff
10	    addq $0x7FFFFFFF, %rax          # OK
1: /x $rax = 0xfffffffe
11	    addq $-0x80000000, %rax         # OK
1: /x $rax = ❶ 0x17ffffffd
12	    addq $0xFFFFFFFF80000000, %rax  # OK (0xFFFFFFFF80000000 = -0x80000000)
1: /x $rax = ❷ 0xfffffffd
main () at add-imm.s:13
13	    ret
1: /x $rax = ❸ 0x7ffffffd
#以下が表示されていれば成功
#1: /x $rax = 0xffffffff
#1: /x $rax = 0xfffffffe
#1: /x $rax = 0x17ffffffd
#1: /x $rax = 0xfffffffd
#1: /x $rax = 0x7ffffffd

$ gcc -g add-imm.s
$ objdump -d ./a.out
0000000000001129 <main>:
    1129:	48 c7 c0 00 00 00 00 	mov    $0x0,%rax
    1130:	83 c0 ff             	add    $0xffffffff,%eax
    1133:	48 83 c0 ff          	add    $0xffffffffffffffff,%rax
    1137:	48 05 ff ff ff 7f    	add    $0x7fffffff,%rax
    113d:	48 05 00 00 00 80    	add    $0xffffffff80000000,%rax
    1143:	48 05 00 00 00 80    	add    $0xffffffff80000000,%rax
    1149:	c3                   	ret    

• mov命令は例外で64ビットの即値を扱えます

# asm/movqabs-1.s
    .text
    .globl main
    .type main, @function
main:
    movq $0x1122334455667788, %rax
    movabsq $0x99AABBCCDDEEFF00, %rax
    ret
    .size main, .-main

$ gcc -g movqabs-1.s
$ gdb ./a.out -x movqabs-1.txt
Breakpoint 1, main () at movqabs-1.s:6
6	    movq $0x1122334455667788, %rax
7	    movabsq $0x99AABBCCDDEEFF00, %rax
1: /x $rax = 0x1122334455667788
main () at movqabs-1.s:8
8	    ret
1: /x $rax = 0x99aabbccddeeff00
# 以下が表示されれば成功
# 1: /x $rax = 0x1122334455667788
# 1: /x $rax = 0x99aabbccddeeff00

• ジャンプでは64ビットの相対ジャンプができないので， 間接ジャンプを使う必要がある

# asm/jmp-64bit.s
    .text
    .globl main
    .type main, @function
main:
#    jmp 0x1122334455667788           # NG
    movq $0x1122334455667788, %rax
    jmp *%rax
    ret
    .size main, .-main

レジスタ

汎用レジスタ

• 上記16個のレジスタが汎用レジスタ(general-purpose register)です． 原則として，プログラマが自由に使えます．
• ただし，%rspはスタックポインタ，%rbpはベースポインタと呼び， 一番上のスタックフレームの上下を指す という役割があります． (ただし，-fomit-frame-pointer オプションでコンパイルされたa.out中では，%rbpはベースポインタとしてではなく， 汎用レジスタとして使われています)．

caller-save/callee-saveレジスタ

引数

• 第7引数以降はレジスタではなくスタックを介して渡します

プログラムカウンタ（命令ポインタ）

ステータスレジスタ（フラグレジスタ）

本書で扱うフラグ

ステータスレジスタのうち，本書は以下の6つのフラグを扱います．

ステータスフラグの変化の記法

x86-64命令を実行すると，ステータスフラグが変化する命令と 変化しない命令があります． ステータスフラグの変化は以下の記法で表します．

記法の意味は以下の通りです．

レジスタの別名

%raxレジスタの別名 (%rbx, %rcx, %rdxも同様)

• %raxの下位32ビットは%eaxとしてアクセス可能
• %eaxの下位16ビットは%axとしてアクセス可能
• %axの上位8ビットは%ahとしてアクセス可能
• %axの下位8ビットは%alとしてアクセス可能

%rbpレジスタの別名 (%rsp, %rdi, %rsiも同様)

• %rbpの下位32ビットは%ebpとしてアクセス可能
• %ebpの下位16ビットは%bpとしてアクセス可能
• %bpの下位8ビットは%bplとしてアクセス可能

%r8レジスタの別名 (%r9〜%r15も同様)

• %r8の下位32ビットは%r8dとしてアクセス可能
• %r8dの下位16ビットは%r8wとしてアクセス可能
• %r8wの下位8ビットは%r8bとしてアクセス可能

同時に使えない制限

• 一部のレジスタは%ah, %bh, %ch, %dhと一緒には使えない．
• 例：movb %ah, (%r8) や movb %ah, %bplはエラーになる．
• 正確にはREXプリフィクス付きの命令では，%ah, %bh, %ch, %dhを使えない．

32ビットレジスタ上の演算は64ビットレジスタの上位32ビットをゼロにする

• 例:movl $0xAABBCCDD, %eaxを実行すると%raxの上位32ビットが全てゼロになる
• 例: movw $0x1122, %axやmovb $0x11, %alでは上位をゼロにすることはない

上位32ビットをゼロにする実行例

# asm/zero-upper32.s
    .text
    .globl main
    .type main, @function
main:
    movq $0x1122334455667788, %rax
    movl $0xAABBCCDD, %eax
    movq $0x1122334455667788, %rax
    movw $0x1122, %ax
    movq $0x1122334455667788, %rax
    movb $0x11, %al
    ret
    .size main, .-main

$ gcc -g zero-upper32.s
$ gdb ./a.out -x zero-upper32.txt
Breakpoint 1, main () at zero-upper32.s:7
7	    movl $0xAABBCCDD, %eax
6	    movq $0x1122334455667788, %rax
7	    movl $0xAABBCCDD, %eax
$1 = 0x1122334455667788
8	    movq $0x1122334455667788, %rax
$2 = 0x00000000aabbccdd
# 以下が出力されれば成功
# $1 = 0x1122334455667788 (%raxは8バイトの値を保持)
# $2 = 0x00000000aabbccdd (%raxの上位4バイトがゼロになった)

アドレッシングモード(オペランドの記法)

アドレッシングモードの種類

• fooはラベルであり，定数と同じ扱い．(定数を書ける場所にはラベルも書ける)．
• メモリ参照では例えば-8(%rbp, %rax, 8)など複雑なオペランドも指定可能． 参照するメモリのアドレスは-8+%rbp+%rax*8になる． (以下を参照)．

メモリ参照の形式

注： Intelのマニュアルには「segment: メモリ参照」という形式もあるとありますが， segment: はほとんど使わないので，省いて説明します．

$ less /proc/cpuinfo
processor       : 0
cpu family      : 6
model name      : Intel(R) Core(TM) i9-9880H CPU @ 2.30GHz
(一部略)
flags           : fpu vme de pse tsc msr pae mce cx8 apic sep mtrr pge mca cmov pat pse36 clflush mmx fxsr sse sse2 ss syscall nx pdpe1gb rdtscp lm constant_tsc arch_perfmon nopl xtopology tsc_reliable nonstop_tsc cpuid tsc_known_freq pni pclmulqdq ssse3 fma cx16 pcid sse4_1 sse4_2 x2apic movbe popcnt tsc_deadline_timer aes xsave avx f16c rdrand hypervisor lahf_lm abm 3dnowprefetch cpuid_fault invpcid_single ssbd ibrs ibpb stibp ibrs_enhanced fsgsbase tsc_adjust bmi1 avx2 smep bmi2 invpcid rdseed adx smap clflushopt xsaveopt xsavec xgetbv1 xsaves arat md_clear flush_l1d arch_capabilities

// tls.c
#include <stdio.h>
❶ __thread int x = 0xdeadbeef;
int main ()
{
    printf ("x=%x\n", x);
}

$ gcc -g tls.c
$ ./a.out
x=deadbeef
$ objdump -d ./a.out | less
0000000000001149 <main>:
    1149:  f3 0f 1e fa             endbr64 
    114d:  55                      push   %rbp
    114e:  48 89 e5                mov    %rsp,%rbp
    1151:  64 8b 04 25 fc ff ff    mov  ❷ %fs:0xfffffffffffffffc,%eax
    1158:  ff 
    1159:  89 c6                   mov    %eax,%esi

$ gdb ./a.out
(gdb) b main
Breakpoint 1 at 0x1151: file tls.c, line 5.
(gdb) r
Breakpoint 1, main () at tls.c:5
5	    printf ("x=%x\n", x);
(gdb) p/x x
$1 = 0xdeadbeef
(gdb) ❸ p/x $fs_base
$2 = ❹ 0x7ffff7fa9740
(gdb) x/1wx $fs_base - 4
0x7ffff7fa973c:	❺ 0xdeadbeef

$ gcc -S -fstack-protector-all add5.c

    .text
    .globl  add5
    .type   add5, @function
add5:
    endbr64
    pushq   %rbp
    movq    %rsp, %rbp
    subq    $32, %rsp
    movl    %edi, -20(%rbp)
    movq ❶ %fs:40, %rax
    movq ❷ %rax, -8(%rbp)
    xorl    %eax, %eax
    movl    -20(%rbp), %eax
    addl    $5, %eax
    movq ❸ -8(%rbp), %rdx
    subq ❹ %fs:40, %rdx
    je      .L3
    call ❺ __stack_chk_fail@PLT
.L3:
    leave   
    ret     
    .size   add5, .-add5

メモリ参照で可能な組み合わせ(64ビットモードの場合)

通常のメモリ参照

• disp には符号あり定数を指定する．ただし「64ビット定数」は無いことに注意． アドレス計算時に64ビット長に符号拡張される． dispは変位(displacement)を意味する．
• base には上記のいずれかのレジスタを指定可能．省略も可．
• index には上記のいずれかのレジスタを指定可能．省略も可． %rspを指定できないことに注意．
• scale を省略すると 1 と同じ

注: dispの例外． mov␣命令のみ，64ビットのdispを指定可能． この場合，movabs␣というニモニックを使用可能． メモリ参照はdispのみで，base，index，scaleは指定不可． 他方のオペランドは%raxのみ指定可能．

movq     0x1122334455667788, %rax
movabsq  0x1122334455667788, %rax
movq     %rax, 0x1122334455667788
movabsq  %rax, 0x1122334455667788

%rip相対参照

%rip相対参照では32ビットのdispと%ripレジスタのみが指定可能です．

メモリ参照の例

• メモリに読み書きするサイズの指定方法 (先頭アドレスだけだと，何バイト読み書きすればいいのか不明):

  • AT&T形式では命令サフィックス (q, l, w, b)で指定する．例: movq $4, 8(%rbp)

  • Intel形式では，メモリ参照の前に QWORD PTR, DWORD PTR, WORD PTR, BYTE PTRを付加する (順番に，8バイト，4バイト，2バイト，1バイトを意味する)． 例: `mov QWORD PTR [rbp+8], 4

「記法」「詳しい記法」欄で用いるオペランドの記法と注意

以下の機械語命令の説明で使う記法を説明します． この記法はその命令に許されるオペランドの形式を表します．

オペランド，即値(定数)

• 多くの場合，サイズを省略して単にimmと書きます． 特にサイズに注意が必要な時だけ，imm32などとサイズを明記します．
• 一部例外を除き， x86-64では64ビットの即値を書けません(32ビットまでです)．

汎用レジスタ

メモリ参照

ジャンプ・コール用のオペランド

• GNUアセンブラの記法のおかしな点

  • 直接ジャンプ先の指定relは，定数なのに$をつけてはいけない
  • 間接ジャンプ先の指定**r/m64は， (他のr/m*オペランドでは不要だったのに) *をつけなくてはいけない
  • 相対アドレスでrel8かrel32をプログラマは選べない (jmp命令に命令サフィックスbやlをつけると怒られる．アセンブラにお任せするしか無い)

• *%raxと*(%rax)の違いに注意(以下の図を参照)

データ転送(コピー)系の命令

mov命令: データの転送（コピー）

• ␣は命令サフィックス
• mov命令(および他のほとんどのデータ転送命令)はステータスフラグの値を変更しない
• mov命令はメモリからメモリへの直接データ転送はできない

xchg命令: オペランドの値を交換

• xchg命令はアトミックに2つのオペランドの値を交換します．(LOCKプリフィクスをつけなくてもアトミックになります)
• このアトミックな動作はロックなどの同期機構を作るために使えます．

lea命令: 実効アドレスを計算

pushとpop命令: スタックとデータ転送

四則演算・論理演算の命令

add, adc命令: 足し算

• addとadcはオペランドが符号あり整数か符号なし整数かを区別せず， 両方の結果を正しく計算する．

sub, sbb命令: 引き算

• addと同様に，subとsbbは オペランドが符号あり整数か符号なし整数かを区別せず， 両方の結果を正しく計算する．

mul, imul命令: かけ算

• オペランドが1つの形式では，%raxが隠しオペランドになる． このため，乗算の前に%raxに値をセットしておく必要がある． また，8バイト同士の乗算結果は最大で16バイトになるので， 乗算結果を%rdxと%raxに分割して格納する (16バイトの乗算結果の上位8バイトを%rdxに，下位8バイトを%raxに格納する)． これをここでは(%rdx:%rax)という記法で表現している．
• imulだけ例外的に，オペランドが2つの形式と3つの形式がある． 2つか3つの形式では乗算結果が64ビットを超えた場合， 越えた分は破棄される(乗算結果は8バイトのみ)．

div, idiv命令: 割り算，余り

• 16バイトの値 %rdx:%rax を第1オペランドで割った商が%raxに入り， 余りが%rdxに入る．
• 隠しオペランドとして%rdxと%raxが使われるので，事前に値を設定しておく必要がある． idivを使う場合，もし%rdxを使わないのであれば， cqto命令で%raxを%rdx:%raxに符号拡張しておくと良い．

inc, dec命令: インクリメント，デクリメント

• incやdecはオーバーフローしてもCFが変化しないところがポイント．

neg命令: 符号反転

not命令: ビット論理演算 (1)

and, or, xor命令: ビット論理演算 (2)

• &, |, ^はC言語で，それぞれ，ビットごとの論理積，論理和，排他的論理積です (忘れた人はC言語を復習しましょう)．

sal, sar, shl, shr命令: シフト

• op1[, op2] という記法は「op2は指定してもしなくても良い」という意味です．
• シフトとは(指定したビット数だけ)右か左にビット列をずらすことを意味します． op2がなければ「1ビットシフト」を意味します．
• 論理シフトとは「空いた場所に0を入れる」， 算術シフトとは「空いた場所に符号ビットを入れる」ことを意味します．
• 左シフトの場合は(符号ビットを入れても意味がないので)，論理シフトでも算術シフトでも，0を入れます．その結果，算術左シフトsalと論理左シフトshlは全く同じ動作になります．
• C言語の符号あり整数に対する右シフト(>>)は算術シフトか論理シフトかは 決まっていません(実装依存です)． C言語で，ビット演算は符号なし整数に対してのみ行うようにしましょう．

rol, ror, rcl, rcr命令: ローテート

• op1[, op2] という記法は「op2は指定してもしなくても良い」という意味です．
• ローテートは，シフトではみ出したビットを空いた場所に入れます．
• ローテートする方向(右か左)，CFを含めるか否かで，4パターンの命令が存在します．

cmp, test命令: 比較

cmp命令

• cmp命令はフラグ計算だけを行います． (レジスタやメモリは変化しません)．
• cmp命令は条件付きジャンプ命令と一緒に使うことが多いです． 例えば以下の2命令で「%raxが(符号あり整数として)1より大きければジャンプする」という意味になります．

cmpq $1, %rax
jg L2

test命令

• cmp命令と同様に，test命令はフラグ計算だけを行います． (レジスタやメモリは変化しません)．
• cmp命令と同様に，test命令は条件付きジャンプ命令と一緒に使うことが多いです． 例えば以下の2命令で「%raxが0ならジャンプする」という意味になります．

testq %rax, %rax
jz L2

• 例えば%raxが0かどうかを知りたい場合， cmpq $0, %raxとtestq %rax, %raxのどちらでも調べることができます． どちらの場合も，ZF==1なら，%raxが0と分かります (testq %rax, %raxはビットごとのANDのフラグ変化を計算するので， %raxがゼロの時だけ，ZF==1となります)． コンパイラはtestq %rax, %raxを使うことが多いです． testq %rax, %raxの方が命令長が短くなるからです．

movs, movz, cbtw, cqto命令: 符号拡張とゼロ拡張

movs, movz命令

• movs, movz命令はAT&T形式とIntel形式でニモニックが異なるので注意です．
• GNUアセンブラではAT&T形式でも実はmovsx, movzxのニモニックが使用できます． ただし逆アセンブルすると，movslq, movzwqなどのニモニックが表示されるので， movslq, movzwqなどを使う方が良いでしょう．
• movzlq (Intel形式ではmovzxd)はありません．例えば，%eaxに値を入れると， %raxの上位32ビットはクリアされるので， movzlqは不要だからです．
• Intel形式では，4バイト→8バイトの拡張の時だけ， (movsxではなく)movsxdを使います．

cbtw, cqto命令

• cqtoなどはidivで割り算する前に使うと便利(%rdx:%raxがidivの隠しオペランドなので)．
• GNUアセンブラはIntel形式のニモニックも受け付ける．

ジャンプ命令

jmp: 無条件ジャンプ

• x86-64では，相対・直接と絶対・間接の組み合わせしかありません． (つまり，相対・間接ジャンプや絶対・直接ジャンプはありません． なお，ここで紹介していないfarジャンプでは絶対・直接もあります)．
• 相対・直接ジャンプでは符号ありの8ビット(rel8)か 32ビット(rel32)の整数定数で相対アドレスを指定します． (64ビットの相対アドレスは指定できません．64ビットのジャンプをしたい時は 絶対・間接ジャンプ命令を使います)．
• rel8かrel32かはアセンブラが勝手に選んでくれます． 逆にjmpbやjmplなどとサフィックスをつけて指定することはできません．
• なぜか，定数なのにrel8やrel32にはドルマーク$をつけません． 逆にr/mの前にはアスタリスク*が必要です． GNUアセンブラのこの部分は一貫性がないので要注意です．

条件付きジャンプの概要

• 条件付きジャンプ命令 j␣は 　ステータスフラグ (CF, OF, PF, SF, ZF)をチェックして， 条件が成り立てばジャンプします．
• 条件付きジャンプは比較命令と一緒に使うことが多いです． 例えば以下の2命令で「%raxが(符号あり整数として)1より大きければジャンプする」という意味になります．

cmpq $1, %rax
jg L2

• 条件付きジャンプ命令のニモニックでは次の用語を使い分けます
  • 符号あり整数の大小には less/greater を使う
  • 符号なし整数の大小には above/below を使う

条件付きジャンプ: 符号あり整数用

• op1 と op2 は条件付きジャンプ命令の直前で使用したcmp命令のオペランドを表します．
• jgとjnleは異なるニモニックですが動作は同じです． その証拠にジャンプ条件はZF==0&&SF==OFと共通です． 他の3つのペア，jgeとjnl，jleとjng，jlとjngeも同様です．

条件付きジャンプ: 符号なし整数用

• op1 と op2 は条件付きジャンプ命令の直前で使用したcmp命令のオペランドを表します．
• jaとjnbeは異なるニモニックですが動作は同じです． その証拠にジャンプ条件はCF==0&&ZF==0と共通です． 他の3つのペア，jaeとjnb，jbeとjna，jbとjnaeも同様です．

条件付きジャンプ: フラグ用

• op1 と op2 は条件付きジャンプ命令の直前で使用したcmp命令のオペランドを表します．
• jzとjeは異なるニモニックですが動作は同じです． その証拠にジャンプ条件はZF==1と共通です． 他の3つのペア，jnzとjne，jpとjpe，jnpとjpoも同様です．
• AFフラグのための条件付きジャンプ命令は存在しません．

関数呼び出し(コール命令)

call, ret命令: 関数を呼び出す，リターンする

enter, leave命令: スタックフレームを作成する，破棄する

• enter命令のop2には関数のネストレベルを指定するのですが， C言語では入れ子の関数がない(つまりネストレベルは常にゼロ)なので 常にゼロを指定します．
• ただし，enterは遅いので通常は使いません． 代わりに同等の動作をするpushq %rbp; movq %rsp, %rbp; subq $n, %rspを使います．

その他

nop命令

• nopは何もしない命令です(ただしプログラムカウンタ%ripは増加します)．
• 機械語命令列の間を(何もせずに)埋めるために使います．
• nopの機械語命令は1バイト長です．
• nop r/m という形式の命令は2〜9バイト長のnop命令になります． 1バイト長のnopを9個並べるより， 9バイト長のnopを1個並べた方が，実行が早くなります．
• 「複数バイトのnop命令がある」という知識は， 逆アセンブル時にnopl (%rax)などを見てビックリしないために必要です．

cmpxchg, cmpxchg8b, cmpxchg16b命令: CAS (compare-and-swap)命令

cmpxchg命令

• cmpxchg命令などのCAS命令は，lock-free，つまりロックを使わず 同期機構を実現するために使われます． アトミックに実行する必要があるため，通常，LOCKプリフィックスをつけて使います．
• 気持ち:
  • あるメモリにあるop2を新しい値op1で書き換えたい．
  • ただし，代入前のop2の値は%raxと同じはずで， もし(割り込まれて)知らない間に別の値になっていたら，この代入は失敗させる．
  • 代入が失敗したことを知るために， (他の誰かが更新した最新の)op2の値を%raxに入れる． cmpxchg実行後に%raxの値を調べれば，無事にop1への代入ができたかどうかが分かる．

cmpxchg8b, cmpxchg16b命令

• cmpxchg8b, cmpxchg16bもCAS命令の一種ですが， cmpxchgとステータスフラグの変化が異なるので，分けて書いています．
• cmpxchg16b命令が参照するメモリは16バイト境界のアラインメントが必要です． (つまりメモリアドレスが16の倍数である必要があります)．

rdtsc, rdtscp命令: タイムスタンプを読む

• x86-64は64ビットのタイムスタンプカウンタ (TSC: time stamp counter)を備えており， リセット後のCPUのサイクル数を数えています． 原理的には「サイクル数の差分をCPUのクロック周波数で割れば実行時間が得られる」 はずですが，実際にはout-of-order実行や， 内部クロックの変化などを考慮する必要があります． 詳しくはHow to Benchmark Code Execution Times on Intel® IA-32 and IA-64 Instruction Set Architectures を参照して下さい．
• rdtscp命令を使うと，プロセッサIDも取得できます． rdtscとrdtscpではシリアライズ処理が異なるため，得られるサイクル数も異なります． 詳しくは x86-64のマニュアルSDM を参照して下さい．

int3命令

• int3命令はブレークポイントトラップ(ソフトウェア割り込みの一種)を発生させます． 通常実行ではint3を実行した時点でプロセスは強制終了となりますが， デバッガ上ではその時点でブレークします．continueコマンドでその後の実行も継続できます．ブレークしたい場所が分かっている場合は， Cコード中にasm ("int3");と書くことでデバッガ上でブレークさせることができます．

ud2命令

• ud2命令は無効オペコード例外を発生させます． 通常実行ではud2を実行した時点でプロセスは， シグナルSIGILL (illegal instruction)を受け取り，強制終了となります デバッガ上でも， Program received signal SIGILL, Illegal instruction. というメッセージが出て，プロセスは終了になります． 本書では「実行が通るはずがない場所が本当かどうか」の確認のため ud2を使います．(通るはずがない場所にud2を置いて，SIGILLが発生しなければOKです)

endbr64命令

• Intel CET IBT技術に対応したCPUの場合， 間接ジャンプ後のジャンプ先がendbr64以外だった場合， 例外が発生してプログラムは強制終了となります．
• Intel CET IBT技術に未対応のCPUの場合は，nop命令として動作します．
• 逆アセンブルしてendbr64を見てもビックリしないためにこの説明を書いています．
• 私のPCが古すぎて，Intel CET未対応だったため，2023/8/17現在，クラッシュが発生するサンプルコードを作れていません．

bndプリフィクス

Intel MPX (Memory Protection Extensions)の機能の一部で， 制御命令 (ジャンプ命令やリターン命令など)に指定できます． BND0からBND3レジスタに指定した境界に対して境界チェックを行います． この機能をサポートしてないCPUではnopとして動作します．

• 逆アセンブルしてbndを見てもビックリしないためにこの説明を書いています．
  以下のようにPLTセクションを見ると❶bndが使われています．

$ objdump -d /bin/ls | less
(中略)
Disassembly of section .plt:

0000000000004030 <.plt>:
    4030:       ff 35 2a dc 01 00       push   0x1dc2a(%rip)        # 21c60 <_ob
stack_memory_used@@Base+0x114b0>
    4036:       f2 ff 25 2b dc 01 00 ❶ bnd jmp *0x1dc2b(%rip)        # 21c68 <_obstack_memory_used@@Base+0x114b8>
    403d:       0f 1f 00                nopl   (%rax)

set␣命令: ステータスフラグの値を取得

• set␣命令はステータスフラグの値を取得します． ␣には条件付きジャンプ命令j␣の␣と同じものをすべて入れられます．

ストリング命令

movsなどのストリング命令はREPプリフィクスと組み合わせて使います．

• REPプリフィクス

注意: DFフラグ(direction flag)が0の場合，%rsiと%rdiを増やす．DFが1の場合は減らす．上記の説明はDF==0を仮定．

注意: ストリング命令はセグメントレジスタ%dsと%esを使って，%ds:(%rsi)と%es:(%rdi)にアクセスします．が，x86-64では%dsも%esもベースレジスタをゼロと扱うので，%dsと%esは無視して構いません．

• ストリング命令

  記法	何の略か	動作
  movs␣	move string	(%rsi)を(%rdi)にnバイト転送; %rsi += n; %rdi += n;
  lods␣	load string	(%rsi)を%raxにnバイト転送; %rsi += n;
  stos␣	store string	%raxを(%rdi)にnバイト転送; %rdi += n;
  ins␣	input string	I/Oポート%dxから(%rdi)にnバイト転送; %rdi += n;
  outs␣	output string	(%rsi)からI/Oポート%dxにnバイト転送; %rsi += n;
  cmps␣	compare string	(%rsi)と(%rdi)をnバイト比較; %rsi += n; %rdi += n;
  scas␣	scan string	%raxと(%rdi)をnバイト比較; %rdi += n;

  詳しい記法	例	例の動作	サンプルコード
  rep movsb	rep movsb	while (%ecx-- > 0) (*%rdi++) = (*%rsi++); # 1バイトずつコピー	rep.s rep.txt
  rep lodsb	rep lodsb	while (%ecx-- > 0) %al = (*%rsi++); # 1バイトずつコピー	lods.s lods.txt
  rep stosq	rep stosq	while (%ecx-- > 0) {(*%rdi) = %rax; %rdi+=8; } # 8バイトずつコピー	stos.s stos.txt
  repe cmpsb	repe cmpsb	while (%ecx-- > 0 && (*%rdi++) == (*%rsi++); # 1バイトずつ比較	repe.s repe.txt
  repne scasb	repne scasb	while (%ecx-- > 0 && (*%rdi++) != %rax); # 1バイトずつ比較	scas.s scas.txt

  • ␣にはb，w，l，qが入り，それぞれ， メモリ参照のサイズ(上ではnと表記)が1バイト，2バイト，4バイト，8バイトになる． (ただし，insとoutsはb，w，lのみ指定可能)．
  • %raxはオペランドサイズにより，%rax，%eax，%ax，%alのいずれかになる．
  • ins␣とout␣の実例はここでは無し．

• DFフラグ(方向フラグ)とcld命令・std命令

  記法	何の略か	動作
  cld	clear direction flag	DF=0
  std	set direction flag	DF=1

  詳しい記法	例	例の動作	サンプルコード
  cld	cld	DF=0	cld.s cld.txt
  std	std	DF=1	cld.s cld.txt

  • DFフラグはストリング命令で，%rsiと%rdiを増減する方向を決めます．
    • DF=0 の時は%rsiと%rdiを増やします
    • DF=1 の時は%rsiと%rdiを減らします
  • DFフラグの変更はcldやstdで行います (一般的にフラグレジスタの値を変更する場合，pushfでフラグレジスタの値を保存し， popfで元に戻すのが安全です)．
  • Linux AMD64のABIにより， 関数の出入り口ではDF=0に戻す必要があります．このお約束のため， 自分でstdしていなければ，必ずDF==0となります(わざわざcldする必要はありません)．